首先是live的地图

package com.ityao.map
{
	import com.google.maps.CopyrightCollection;
	import com.google.maps.TileLayerBase;

	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.events.IEventDispatcher;
	import flash.events.IOErrorEvent;
	import flash.geom.Point;
	import flash.net.URLRequest;

	public class LiveDituTileLayerBase extends TileLayerBase
	{
		private var serviceUrls:Array=["http://r0.tiles.ditu.live.com/tiles/r",
									   "http://r1.tiles.ditu.live.com/tiles/r",
									   "http://r2.tiles.ditu.live.com/tiles/r",
									   "http://r3.tiles.ditu.live.com/tiles/r"];
		private var serviceUrlSuffix:String = ".png?g=29";

		public function LiveDituTileLayerBase()
		{
			super(new CopyrightCollection("http://cn.bing.com/ditu/"),0,19)
		}

		private function getTileUrl(p:Point,zoom:int):String{			

			var c:Number=Math.pow(2,zoom);
			var d:Number=p.x;
			var e:Number=p.y;
			var f:String="";
			for(var g:int=0;g<zoom;g++){
				c=c/2;
				if(e<c){
					if(d<c){
						f+="0"
					}else{
						f+="1";
						d-=c
					}
				}else{
					if(d<c){
						f+="2";
						e-=c
					}else{
						f+="3";
						d-=c;
						e-=c
					}
				}
			}
			var h:int=(p.x+p.y)%serviceUrls.length;
			return serviceUrls[h]+f+serviceUrlSuffix;

		}	

		public override function loadTile(tilePos:Point, zoom:Number):DisplayObject{

			var loader:Loader = new Loader();
			configureListeners(loader.contentLoaderInfo);
			var url:String = getTileUrl(tilePos,zoom);
			var tileUrl:URLRequest = new URLRequest(url);
			trace(tilePos.toString()+" z:"+zoom + " url:"+url);
			loader.load(tileUrl);
			return loader;

		}

		private function configureListeners(dispatcher:IEventDispatcher):void{
			dispatcher.addEventListener(IOErrorEvent.IO_ERROR,_secondaryLoad);
		} 

		private function _secondaryLoad(event:IOErrorEvent):void{
			//image fail to load handler
		}
	}
}

然后是mapABC的地图

package com.ityao.map
{
	import com.google.maps.CopyrightCollection;
	import com.google.maps.TileLayerBase;

	import flash.display.DisplayObject;
	import flash.display.Loader;
	import flash.events.IEventDispatcher;
	import flash.events.IOErrorEvent;
	import flash.geom.Point;
	import flash.net.URLRequest;

	public class MapABCDituTileLayerBase extends TileLayerBase{

		public function MapABCDituTileLayerBase(){
			super(new CopyrightCollection("http://www.mapabc.com"),0,17)
		}

		private function getTileUrl(p:Point,zoom:int):String{
			var url:String = "http://emap" + ((p.x + p.y) % 4) + ".mapabc.com/mapabc/maptile?v=";
			url += "w2.99" ;
			url += "&x=" + p.x + "&y=" + p.y + "&zoom=" + (17-zoom);
			return url;
		}	

		public override function loadTile(tilePos:Point, zoom:Number):DisplayObject{

			var loader:Loader = new Loader();
			configureListeners(loader.contentLoaderInfo);
			var url:String = getTileUrl(tilePos,zoom);
			var tileUrl:URLRequest = new URLRequest(url);
			trace(tilePos.toString()+" z:"+zoom + " url:"+url);
			loader.load(tileUrl);
			return loader;

		}

		private function configureListeners(dispatcher:IEventDispatcher):void{
			dispatcher.addEventListener(IOErrorEvent.IO_ERROR,_secondaryLoad);
		} 

		private function _secondaryLoad(event:IOErrorEvent):void{
			//image fail to load handler
		}
	}
}

在上面的例子可以看见，其实只要重载loadTile方法就可以了，是不是非常简单？

loadTile的第一个参数是图块坐标，第二个参数是zoom的图层深度
这里有篇很好的文章和实例演示告诉你这些参数是怎么来的，
http://www.maptiler.org/google-maps-coordinates-tile-bounds-projection/

使用这两个参数，我们要针对不用的图瓦（live或mapABC）去构造图瓦的链接，从而用一块块图瓦拼接出完整的地图。

图瓦的链接是怎么获得的呢？
呵呵，可以是根据不同地图的文档说明（不过通常都很少），通常我在看一个地图的时候，用firefox进行浏览，然后打开”工具”->”页面信息”，如下图所示：

然后就发挥你的小宇宙，去猜猜那串图瓦链接怎么来的，呵呵！
我把live的猜出来了，欢迎大家补充别的链接。

不过自己毕竟不是GIS科班出身，也没从事过GIS或者地图的真正商业开发，研究地图应用开发，纯属兴趣，所以不足之处，敬请斧正:)

构建Flex地图应用，首选Google的地图API来实现，有以下原因：

1. 支持自定义扩展地图类型
2. 有丰富的图形标注工具
3. 有多种数据接口
4. 详细的文档支持

Google map API的这些特点，可以使我们快速地开发出各式各样的地图web应用，由于本帖不是替google map打广告，就不一一介绍这些特点的详细情况了，本帖更关注于第一个特点，利用Google map api来构建属于自己的地图。

或者大家会问：构建自己的地图？可以是什么样子的呢？
小弟天马行空地替大家想象了一下，我初步想大家可以构建这样的一些应用：

• 在专业的地图服务器里写script导出图瓦（动态或静态），然后制作自己的地图应用，最好的例子就是google地图本身
• 利用网络的地图图瓦资源，构造地图应用，如利用API来显示e都市的三维地图，或者如后面演示的显示别的厂商如google的对手bingo的地图，mapABC的地图等
• 通过修改现成的地图图瓦，来创造自己的地图。呵呵，站在巨人的肩膀上啊，例如你可以抓取google的图瓦，把上面的藏南地区全改回中文，然后发布出去
• 发布大型的图画作品，例如你是卖画或者什么别的艺术品，或者你要做游戏地图，可以把照片割成图瓦，挂到网上去，让大家可以在不同分辨层次下欣赏作品
• 协同进行艺术创作，把地图想象成大图画，大家可以在一个图画上创作，通过Map API可以进行宏观创作或者细节创作
• … 更多更多好点子，欢迎在评论里面留言

首先贴一个swf，给大家看看用Google Map API来显示Live地图和MapABC地图的效果。

实现这个效果的步骤如下：

1. 使用Flex的google map api，首先要去这里 下载
2. 注册一个api使用的key，在这个页面进行注册
3. 创建flex项目，项目目录结构如下图所示：
   
   前面下载的SDK里面的map_flex_1_16.swc（下载时间不同，可能版本号不一致）需要放在项目的lib目录里面去。
4. 创建mapsample.mxml主程序，代码如下：

   <?xml version="1.0" encoding="utf-8"?>
   <mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
   	<maps:Map xmlns:maps="com.google.maps.*" language="zh-CN" id="map"
   		mapevent_mapready="onMapReady(event)"
   		width="100%" height="100%" key="{mapKey}"/>
   	<mx:Script>
   		<![CDATA[
   			import com.ityao.map.MapABCDituTileLayerBase;
   			import com.ityao.map.GoogleDituTileLayerBase;
   			import com.ityao.map.LiveDituTileLayerBase;			
   
   			import com.google.maps.overlays.TileLayerOverlay;
   			import com.google.maps.controls.MapTypeControl;
   			import com.google.maps.controls.PositionControl;
   			import com.google.maps.controls.ZoomControl;
   			import com.google.maps.LatLng;
   			import com.google.maps.Map;
   			import com.google.maps.MapEvent;
   			import com.google.maps.MapType;    
   
   			//key for http://blog.ityao.com/
   			private static const mapKey:String = "ABQIAAAAjg2LNPeLd2SY_LMC4kTfyhREhvxbmPPYdzuafsMTRfCiNgtm-xT_QN9uPU6M7JTAKA4l_ycXr_8HOg";
   			private function onMapReady(event:Event):void {				      
   
   				map.addControl(new ZoomControl());
   				map.addControl(new PositionControl());
   				map.addControl(new MapTypeControl());
   				map.removeMapType(MapType.PHYSICAL_MAP_TYPE);
   				map.removeMapType(MapType.SATELLITE_MAP_TYPE);
   				map.removeMapType(MapType.HYBRID_MAP_TYPE);
   
   				//Live地图
   				var liveTileBase:LiveDituTileLayerBase = new LiveDituTileLayerBase();
   				var liveTileLayers:Array = new Array();
   				liveTileLayers.push(liveTileBase);
   				var liveMapType:MapType = new MapType(liveTileLayers,map.MERCATOR_PROJECTION,"Live地图");
   				liveTileBase.setMapType(liveMapType);
   				map.addMapType(liveMapType);
   
   				//mapABC地图
   				var mapABCDituTileLayerBase:MapABCDituTileLayerBase = new MapABCDituTileLayerBase();
   				var mapABCDituTileLayers:Array = new Array();
   				mapABCDituTileLayers.push(mapABCDituTileLayerBase);
   				var mapABCDituMapType:MapType = new MapType(mapABCDituTileLayers,map.MERCATOR_PROJECTION,"mapABC地图");
   				mapABCDituTileLayerBase.setMapType(mapABCDituMapType);
   				map.addMapType(mapABCDituMapType);
   				//设置缺省的地图中心和地图类型
   				map.setCenter(new LatLng(23.09656,113.19219), 10);
   			}
   		]]>
   	</mx:Script>
   </mx:Application>
   

   注意需要在程序中修改mapKey变量成为你前面注册的google map api key。

5. 在主程序里面，我们创建了两种自定义的地图类型，并且添加了这两种类型进google地图中进行显示

定制自定义地图，如果地图的投影方法和google map一致的话，那只要继承TileLayerBase并重载里面的loadTile（加载图瓦）方法就可以了，下一篇将用live地图和mapABC地图为大家做介绍。